swadhinbiswas Initial de-omarchy: Omarchy UI layer for Arch-based distros · 8/22/2026
9f393b2
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
import QtQuick
import Quickshell.Io
import "NightlightModel.js" as NightlightModel
Item {
id: root
// Injected by omarchy-shell (the first-party service loader).
property var shell: null
// Keep in sync with bin/omarchy-toggle-nightlight, which sets the same
// temperatures for callers outside the shell (keybindings, menu, ssh).
readonly property int nightTemperature: 4000
readonly property int dayTemperature: 6500
property bool stateLoaded: false
property var temperature: null
readonly property bool enabled: stateLoaded && NightlightModel.isNightlight(temperature)
property bool hasPendingTemperature: false
property int pendingTemperature: 0
function refresh() {
if (!statusProbe.running) statusProbe.running = true
}
function setNightlight(value) {
applyTemperature(value ? nightTemperature : dayTemperature)
}
function toggle() {
setNightlight(!enabled)
}
function applyTemperature(temp) {
root.temperature = temp
root.stateLoaded = true
if (applyProcess.running) {
root.pendingTemperature = temp
root.hasPendingTemperature = true
return
}
runApply(temp)
}
function runApply(temp) {
applyProcess.command = ["bash", "-lc",
"pgrep -x hyprsunset >/dev/null || { setsid uwsm-app -- hyprsunset >/dev/null 2>&1 & sleep 1; }; " +
"hyprctl hyprsunset temperature " + Number(temp)]
applyProcess.running = true
}
Process {
id: statusProbe
command: ["hyprctl", "hyprsunset", "temperature"]
stdout: StdioCollector {
waitForEnd: true
onStreamFinished: {
root.temperature = NightlightModel.temperatureFromOutput(text)
root.stateLoaded = true
}
}
onExited: function(exitCode) {
if (exitCode !== 0) {
root.temperature = null
root.stateLoaded = true
}
}
}
Process {
id: applyProcess
onExited: function() {
if (root.hasPendingTemperature) {
root.hasPendingTemperature = false
root.runApply(root.pendingTemperature)
return
}
root.refresh()
}
}
Component.onCompleted: refresh()
IpcHandler {
target: "nightlight"
function status(): string {
return JSON.stringify({ enabled: root.enabled, temperature: root.temperature })
}
function refresh(): void {
root.refresh()
}
function enable(): string {
root.setNightlight(true)
return "enabled"
}
function disable(): string {
root.setNightlight(false)
return "disabled"
}
function toggle(): string {
var enabling = !root.enabled
root.setNightlight(enabling)
return enabling ? "enabled" : "disabled"
}
}
}